Office-Blog

Mein Beitrag vom 26.03.2025 beschreibt, wie automatische Zahlenreihen, Nummerierungen und Wochentagslisten mit Hilfe der Funktion SEQUENZ erzeugt werden. Auch für das automatische Generieren von Datums- und Uhrzeitreihen ist SEQUENZ erste Wahl.

Wie das geht und wie interaktive Steuerelemente dabei den Bedienkomfort verbessern, zeige ich im folgenden Beitrag.

Listen mit beliebig vielen fortlaufenden Monatsnamen generieren

Für Kalender, Terminplanung, Formulare mit Dropdown-Liste, Analysen, Berichte oder im Projektmanagement werden Monatslisten gebraucht. Soll die Anzahl der Monatsnamen flexibel veränderbar sein, ist SEQUENZ das passende Tool.

Funktioniert bei Wochentagen, jedoch nicht bei Monatsnamen

• Wer den Beitrag vom 26.03.2025 gelesen hat, weiß, dass folgende Formel eine fortlaufende Liste mit 14 Wochentagen erzeugt: =TEXT(SEQUENZ(14; ;2); „TTTT“).
• Um eine Liste mit Monatsnamen zu erhalten, reicht es allerdings nicht, das Argument Textformat einfach abzuändern von „TTTT“ auf „MMMM“. Zusätzlich wird noch die Funktion DATUM gebraucht.

Gut zu wissen: Wie die Funktion DATUM arbeitet

Mit der Funktion lassen sich Datumsangaben dynamisch aus Zelleinträgen oder Formelergebnissen zusammensetzen.

Ein Datum wird aus den folgenden drei Komponenten erstellt:

• Jahr,
• Monat,
• Tag.

Eine Liste mit beliebig vielen fortlaufenden Monatsnamen generieren

In der folgenden Abbildung werden per Formel zwei Monatslisten erzeugt. Ihre Länge wird durch die Eingabe in die hellblauen Zellen (hier B3 und E3) gesteuert.

• Dazu wird SEQUENZ für das Argument Monat in die Funktion DATUM eingebaut.
• Die Formel zum Erzeugen einer fortlaufenden Liste mit Monatsnamen – hier sechs – wäre demzufolge =DATUM(0; SEQUENZ(B3; 1); 1).
• Allerdings hat diese Formel den Nachteil, dass allen Zellen nachträglich noch das Zahlenformat „MMMM“ oder „MMM“ zugewiesen werden muss. Bei einer sich ändernden Länge der Liste wäre das nicht effizient.
• Daher umschließe ich die Formel wieder mit der Funktion TEXT. So kann ich steuern, dass die Monatsnamen gleich wie gewünscht angezeigt werden:
  ausgeschrieben mit der Textformat-Anweisung „MMMM“ oder abgekürzt mit „MMM“.
• Demzufolge lautet die Formel, die in der oben gezeigten Abbildung ab Zelle B5 automatisch eine Monatsliste mit den in B3 angegeben 6 Monaten erzeugt
  =TEXT(DATUM(0; SEQUENZ(B3); 1); „MMMM“).

WICHTIG: Der Wert, der für das Argument Jahr in die Funktion DATUM eingegeben wird, kann eine beliebige Zahl von 0 bis 9999 sein. Auf eine bestimmte Jahreszahl kommt es nicht an, weil jedes Jahr gleich viele Monate hat, nämlich 12.

Flexible Datumslisten generieren und interaktiv steuern

Für einen Dienstplan sollen die 365 Kalendertage des Jahres untereinander als Datum erscheinen?

In einem Bericht werden für die nächsten 24 Monate die Datumsangaben zu Monatsanfang und Monatsende gebraucht?

Solche Aufgaben lassen sich mittels AutoAusfüllkästchen erledigen. Was aber wenn sich die Länge der Liste ändern soll? Dann muss manuell nachgebessert werden. Besser ist eine Formel-Lösung. Die folgende Abbildung zeigt, wie Beginn und Länge der Datumslisten interaktiv durch die Steuerelemente in Spalte D jederzeit leicht angepasst werden können.

Beispiel 1: Eine flexibel steuerbare Datumsliste

• Die in der oben gezeigten Abbildung in Spalte F erzeugte Datumsliste wird mit der folgenden Formel erzeugt:
  =SEQUENZ(C9; 1; DATUM(JAHR(HEUTE()); 1; 1); 1)
• Über die Drehfelder in Spalte D neben den Zellen mit den Angaben zu Jahr, Tag und Monate lässt sich der Beginn und die Länge der Datumsliste ganz leicht steuern.

Beispiel 2: Eine Datumsliste mit den Monatsersten

Für die nächsten x Monate soll jeweils der Monatserste untereinander aufgelistet werden?

• Kein Problem mit der Formel =DATUM(C5; SEQUENZ(C9; 1); C7)
• Über die Drehfelder neben C5 und C9 lässt sich steuern, wann die Monatsreihe beginnt und wie lang sie ist.
• Wird nicht der Monatserste, sondern beispielsweise der 10. oder 15. oder 20. des jeweiligen Monats gebraucht, reicht es, den gewünschten Wert in Zelle C7 zu ändern.

Beispiel 3: Eine Datumsliste mit den Monatsletzten

Am Monatsende sollen Kosten, Umsätze, Überstunden, Krankheitstage oder Fehlerquoten erfasst werden? Gebraucht wird also eine Liste mit x Einträgen zum Monatsende.

• Die folgende Formel erzeugt eine Liste mit Datumsangaben für den jeweils Monatsletzten:
  =MONATSENDE(DATUM(C5; SEQUENZ(C9; 1); 1); 0)
• Über die Drehfelder neben C5 und C9 wird gesteuert, wann die Monatsreihe beginnt und wie lang sie ist.

Damit das Datumsformat stimmt

In den eben genannten drei Beispielen für automatisch generierte Datumslisten muss jeweils noch das Zahlenformat der Zellen manuell auf Datum kurz – also auf TT.MM.JJJJ – eingestellt werden.

Wer diese Formatierung automatisch in der Formel erledigen möchte, nutzt diese erweiterten Versionen der drei Formeln:

=TEXT(SEQUENZ(C9; 1; DATUM(JAHR(HEUTE());1;1);1); „TT.MM.JJJJ“)

=TEXT(DATUM(C5; SEQUENZ(C9; 1); C7); „TT.MM.JJJJ“)

=TEXT(MONATSENDE(DATUM(C5; SEQUENZ(C9; 1); 1); 0);“TT.MM.JJJJ“)

Hinweis: Obwohl die so generierten Datumsangaben als TEXT linksbündig in den Zellen erscheinen, kann mit ihnen noch gerechnet werden.

Uhrzeitlisten mit Start und Ende sowie Minutenintervall erzeugen

Listen mit regelmäßigen Zeitintervallen werden beispielsweise für Dienstpläne, Abfahrtzeiten, Zeiterfassung oder Messungen gebraucht. Mit SEQUENZ lassen sich im Nu Listen mit Uhrzeiten erzeugen, bei denen Start- und Endzeit sowie ein Minutenintervall vorgegeben werden können.

Variante 1: Eine einfache Formel mit festen Werten

• Soll beispielsweise eine Liste mit Uhrzeiten im 30-Minuten-Takt von 6:00 bis 9:00 erzeugt werden, reicht folgende einfache Formel =SEQUENZ(7; 1; ZEIT(6; 0; 0); 1/48)
• Anschließend muss den Zellen noch das Uhrzeitformat hh:mm zugewiesen werden.

Variante 2: Komplett flexibel mit Zellbezügen

Flexibler ist es, wenn sich die Angaben zu Beginn, Ende und Intervall leicht und schnell ändern lassen. Eine Lösung dafür zeigt folgende Abbildung.

Die vier Argumente von SEQUENZ – Anzahl, Spalten, Startzeit und Schrittweite – werden dabei wie folgt genutzt:

• Anzahl: Wie viele Einträge die Liste enthalten soll, wird hier nicht durch das Eingeben einer Zahl festgelegt. Stattdessen stehen Start- und Endzeit in den Zellen C3 und C4. Die Anzahl der Einträge wird aus Endzeit minus Startzeit plus 1 berechnet.
• Spalten: Die Liste soll in einer Spalte stehen soll. Daher wird hier eine 1 eingetragen.
• Startzeit: Statt der Funktion ZEIT  wird der Startwert verwendet, in einer Zelle steht, auf die in der Formel Bezug genommen wird. Hier im Beispiel ist es Zelle C3.
• Schrittweite: An der Stelle wird das gewünschte Zeitintervall festgelegt – beispielsweise alle 5, 10, 15 oder 30 Minuten.

Hier zwei konkrete Beispiele:

• Für die links in der Abbildung gezeigte Uhrzeitliste von 06:00 bis 07:00 im 5-Minuten-Takt lautet die Formel dann
  =SEQUENZ((C4-C3)*H7+1;1;C3;1/H7)
• Die Lösung rechts von 06:00 bis 09:00 im 20-Minuten-Takt wird mit folgender Formel erzeugt
  =SEQUENZ((C4-C3)*H4+1;1;C3;1/H4)
• In beiden Fällen muss anschließend noch für die Zellen in der Uhrzeitliste das Zahlenformat hh:mm zugewiesen werden.

Variante 3: Mit passender Formatierung und automatischer Wahl des passenden Koeffizienten

Besser ist es, wenn das nachträgliche Zuweisen des Uhrzeitformats entfallen kann. Dazu wird die Formel wieder in die Funktion TEXT eingeschlossen.

Je nach gewünschtem Minutenintervall muss in der Formel der entsprechende Koeffizient aus Spalte H verwendet werden. Das lässt sich über die Funktion SVERWEIS erledigen.

Für eine Uhrzeitenliste mit flexibel einstellbarem Start, Ende und Intervall lautet die Formel dann
=TEXT(SEQUENZ((C4-C3)*SVERWEIS(E3;G3:H7;2;FALSCH)+1;1;C3;1/SVERWEIS(E3;G3:H7;2;FALSCH));“hh:mm“)