// Kalender
let

  // 1. Januar des Jahres der ersten Bestellung
  StartDatum = Date.StartOfYear(List.Min(Tabelle[Spalte])), 

// 31.12. des laufenden Jahres
  EndDatum = Date.From(Date.EndOfYear(DateTime.LocalNow())), 

// Liste mit fortlaufenden Tagen
  #"Datumsliste erstellen" = List.Dates(
    StartDatum, 
    Number.From(EndDatum - StartDatum) + 1, 
    Duration.From(1)
  ), 

// Liste in einspaltige Tabelle umwandeln
  #"Liste in Tabelle konvertieren" = Table.FromList(
    #"Datumsliste erstellen", 
    Splitter.SplitByNothing(), 
    type table[Datum = Date.Type], 
    null, 
    ExtraValues.Error
  ), 

// Spalte mit Jahreszahl (ganze Zahl)
  #"Spalte Jahr" = Table.AddColumn(
    #"Liste in Tabelle konvertieren", 
    "Jahr", 
    each Date.Year([Datum]), 
    Int64.Type
  ), 

// Spalte mit dem (deutschen) Namen des Monats
  #"Spalte Monat" = Table.AddColumn(
    #"Spalte Jahr", 
    "Monat", 
    each Date.MonthName([Datum], "de-DE"), 
    type text
  ), 

// wird zur kalendarischen Sortierung der Monatnamen benötigt. Ansonsten würden sie alphabetisch sortiert
  #"Spalte MonatSortBy" = Table.AddColumn(
    #"Spalte Monat", 
    "MonatSortBy", 
    each Date.Month([Datum]), 
    Int64.Type
  )
in
  #"Spalte MonatSortBy"